xref: /glogg/glogg.pro (revision 0ef7fbb1f7d844f0516b0c7c203905cc68940bd9) 
1# -------------------------------------------------
2# glogg
3# -------------------------------------------------
4TARGET = glogg
5TEMPLATE = app
6
7win32:Debug:CONFIG += console
8
9# Input
10SOURCES += main.cpp \
11    mainwindow.cpp \
12    crawlerwidget.cpp \
13    abstractlogdata.cpp \
14    logdata.cpp \
15    logfiltereddata.cpp \
16    abstractlogview.cpp \
17    logmainview.cpp \
18    filteredview.cpp \
19    optionsdialog.cpp \
20    configuration.cpp \
21    filtersdialog.cpp \
22    filterset.cpp \
23    savedsearches.cpp \
24    infoline.cpp
25
26HEADERS += version.h \
27    mainwindow.h \
28    crawlerwidget.h \
29    logmainview.h \
30    log.h \
31    filteredview.h \
32    abstractlogdata.h \
33    logdata.h \
34    logfiltereddata.h \
35    abstractlogview.h \
36    optionsdialog.h \
37    configuration.h \
38    filtersdialog.h \
39    filterset.h \
40    savedsearches.h \
41    infoline.cpp
42
43greaterThan(QT_VERSION, "4.4.0") {
44    FORMS += filtersdialog.ui
45}
46else {
47    message(Using old FiltersDialog)
48    FORMS += filtersdialog_old.ui
49}
50
51# For Windows icon
52RC_FILE = glogg.rc
53RESOURCES = glogg.qrc
54
55# Install (for unix)
56icon16.path  = $$PREFIX/share/icons/hicolor/16x16/apps
57icon16.files = images/hicolor/16x16/glogg.png
58
59icon32.path  = $$PREFIX/share/icons/hicolor/32x32/apps
60icon32.files = images/hicolor/32x32/glogg.png
61
62doc.path  = $$PREFIX/share/doc/glogg
63doc.files = README.textile COPYING
64
65desktop.path = $$PREFIX/share/applications
66desktop.path = glogg.desktop
67
68target.path = $$PREFIX/bin
69INSTALLS = target icon16 icon32 doc desktop
70
71# Build directories
72debug:OBJECTS_DIR = $${OUT_PWD}/.obj/debug-shared
73release:OBJECTS_DIR = $${OUT_PWD}/.obj/release-shared
74debug:MOC_DIR = $${OUT_PWD}/.moc/debug-shared
75release:MOC_DIR = $${OUT_PWD}/.moc/release-shared
76
77Release:DEFINES += FILELOG_MAX_LEVEL=\"logERROR\"
78Debug:DEFINES += FILELOG_MAX_LEVEL=\"logDEBUG\"
79
80# Official builds can be generated with `qmake VERSION="1.2.3"'
81isEmpty(VERSION) {
82    QMAKE_CXXFLAGS += -DGLOGG_DATE=\\\"`date +'\"%F\"'`\\\"
83    QMAKE_CXXFLAGS += -DGLOGG_VERSION=\\\"`git describe`\\\"
84    QMAKE_CXXFLAGS += -DGLOGG_COMMIT=\\\"`git rev-parse --short HEAD`\\\"
85}
86else {
87    QMAKE_CXXFLAGS += -DGLOGG_VERSION=\\\"$$VERSION\\\"
88}
89