xref: /glogg/glogg.pro (revision 3e90fb01e8660cd081f3dece6763cf356c67921f) 
1# -------------------------------------------------
2# glogg
3# -------------------------------------------------
4TARGET = glogg
5TEMPLATE = app
6
7win32:Debug:CONFIG += console
8
9# Input
10SOURCES += main.cpp \
11    mainwindow.cpp \
12    crawlerwidget.cpp \
13    abstractlogdata.cpp \
14    logdata.cpp \
15    logfiltereddata.cpp \
16    abstractlogview.cpp \
17    logmainview.cpp \
18    filteredview.cpp \
19    optionsdialog.cpp \
20    configuration.cpp \
21    filtersdialog.cpp \
22    filterset.cpp \
23    savedsearches.cpp \
24    infoline.cpp \
25    logdataworkerthread.cpp \
26    logfiltereddataworkerthread.cpp \
27    filewatcher.cpp
28
29HEADERS += version.h \
30    mainwindow.h \
31    crawlerwidget.h \
32    logmainview.h \
33    log.h \
34    filteredview.h \
35    abstractlogdata.h \
36    logdata.h \
37    logfiltereddata.h \
38    abstractlogview.h \
39    optionsdialog.h \
40    configuration.h \
41    filtersdialog.h \
42    filterset.h \
43    savedsearches.h \
44    infoline.h \
45    logdataworkerthread.h \
46    logfiltereddataworkerthread.h \
47    filewatcher.h
48
49isEmpty(USE_NATIVE_BOOST) {
50    message(Building using static Boost libraries included in the tarball)
51
52    SOURCES += boost/libs/program_options/src/*.cpp \
53        boost/libs/detail/*.cpp \
54        boost/libs/smart_ptr/src/*.cpp
55
56    INCLUDEPATH += ./boost
57}
58else {
59    message(Building using native dynamic Boost libraries)
60    LIBS += -lboost_program_options -L$HOME/lib/
61}
62
63greaterThan(QT_VERSION, "4.4.0") {
64    FORMS += filtersdialog.ui
65}
66else {
67    message(Using old FiltersDialog)
68    FORMS += filtersdialog_old.ui
69}
70
71# For Windows icon
72RC_FILE = glogg.rc
73RESOURCES = glogg.qrc
74
75# Install (for unix)
76icon16.path  = $$PREFIX/share/icons/hicolor/16x16/apps
77icon16.files = images/hicolor/16x16/glogg.png
78
79icon32.path  = $$PREFIX/share/icons/hicolor/32x32/apps
80icon32.files = images/hicolor/32x32/glogg.png
81
82doc.path  = $$PREFIX/share/doc/glogg
83doc.files = README.textile COPYING
84
85desktop.path = $$PREFIX/share/applications
86desktop.path = glogg.desktop
87
88target.path = $$PREFIX/bin
89INSTALLS = target icon16 icon32 doc desktop
90
91# Build directories
92debug:OBJECTS_DIR = $${OUT_PWD}/.obj/debug-shared
93release:OBJECTS_DIR = $${OUT_PWD}/.obj/release-shared
94debug:MOC_DIR = $${OUT_PWD}/.moc/debug-shared
95release:MOC_DIR = $${OUT_PWD}/.moc/release-shared
96
97Release:DEFINES += FILELOG_MAX_LEVEL=\"logERROR\"
98Debug:DEFINES += FILELOG_MAX_LEVEL=\"logDEBUG\"
99
100# Official builds can be generated with `qmake VERSION="1.2.3"'
101isEmpty(VERSION) {
102    QMAKE_CXXFLAGS += -DGLOGG_DATE=\\\"`date +'\"%F\"'`\\\"
103    QMAKE_CXXFLAGS += -DGLOGG_VERSION=\\\"`git describe`\\\"
104    QMAKE_CXXFLAGS += -DGLOGG_COMMIT=\\\"`git rev-parse --short HEAD`\\\"
105}
106else {
107    QMAKE_CXXFLAGS += -DGLOGG_VERSION=\\\"$$VERSION\\\"
108}
109