xref: /glogg/glogg.pro (revision 6281910632bfca8f4657ac05caaf18b23b7d39d3) 
1# -------------------------------------------------
2# glogg
3# -------------------------------------------------
4TARGET = glogg
5TEMPLATE = app
6
7win32:Debug:CONFIG += console
8
9# Input
10SOURCES += main.cpp \
11    mainwindow.cpp \
12    crawlerwidget.cpp \
13    abstractlogdata.cpp \
14    logdata.cpp \
15    logfiltereddata.cpp \
16    abstractlogview.cpp \
17    logmainview.cpp \
18    filteredview.cpp \
19    optionsdialog.cpp \
20    configuration.cpp \
21    filtersdialog.cpp \
22    filterset.cpp \
23    savedsearches.cpp \
24    infoline.cpp \
25    logdataworkerthread.cpp
26
27HEADERS += version.h \
28    mainwindow.h \
29    crawlerwidget.h \
30    logmainview.h \
31    log.h \
32    filteredview.h \
33    abstractlogdata.h \
34    logdata.h \
35    logfiltereddata.h \
36    abstractlogview.h \
37    optionsdialog.h \
38    configuration.h \
39    filtersdialog.h \
40    filterset.h \
41    savedsearches.h \
42    infoline.h \
43    logdataworkerthread.h
44
45greaterThan(QT_VERSION, "4.4.0") {
46    FORMS += filtersdialog.ui
47}
48else {
49    message(Using old FiltersDialog)
50    FORMS += filtersdialog_old.ui
51}
52
53# For Windows icon
54RC_FILE = glogg.rc
55RESOURCES = glogg.qrc
56
57# Install (for unix)
58icon16.path  = $$PREFIX/share/icons/hicolor/16x16/apps
59icon16.files = images/hicolor/16x16/glogg.png
60
61icon32.path  = $$PREFIX/share/icons/hicolor/32x32/apps
62icon32.files = images/hicolor/32x32/glogg.png
63
64doc.path  = $$PREFIX/share/doc/glogg
65doc.files = README.textile COPYING
66
67desktop.path = $$PREFIX/share/applications
68desktop.path = glogg.desktop
69
70target.path = $$PREFIX/bin
71INSTALLS = target icon16 icon32 doc desktop
72
73# Build directories
74debug:OBJECTS_DIR = $${OUT_PWD}/.obj/debug-shared
75release:OBJECTS_DIR = $${OUT_PWD}/.obj/release-shared
76debug:MOC_DIR = $${OUT_PWD}/.moc/debug-shared
77release:MOC_DIR = $${OUT_PWD}/.moc/release-shared
78
79Release:DEFINES += FILELOG_MAX_LEVEL=\"logERROR\"
80Debug:DEFINES += FILELOG_MAX_LEVEL=\"logDEBUG\"
81
82# Official builds can be generated with `qmake VERSION="1.2.3"'
83isEmpty(VERSION) {
84    QMAKE_CXXFLAGS += -DGLOGG_DATE=\\\"`date +'\"%F\"'`\\\"
85    QMAKE_CXXFLAGS += -DGLOGG_VERSION=\\\"`git describe`\\\"
86    QMAKE_CXXFLAGS += -DGLOGG_COMMIT=\\\"`git rev-parse --short HEAD`\\\"
87}
88else {
89    QMAKE_CXXFLAGS += -DGLOGG_VERSION=\\\"$$VERSION\\\"
90}
91